1 '      Gluecks-Rad (R)            written by FLORIAN CASPAR
2 ' (c) 1993 by FC&co.kg.eN*
3 ' (P) by MERV GRIFFIN / SAT.1
4 ' ***************************
5 CLS:PRINT "INIT GLUECKSRAD";
6 CLEAR:DEFSEG=0:IFPEEK1773>0THENEND
7 IFFRE(2)<4*1024THENCLS:PRINT"OM error (mind. 4 kB)";:END
8 GOSUB4400
9 IFPEEK(1867)=58THENGOSUB#3
10 CLS:CLEAR:WK=100:DIMW$(WK+1),D(WK),W(WK),TP$(6),NM$(3),GR$(80),ME(3),MG(3),ME$(3):A=1:RU=1:PL=1
12 DEFCHR$(252)="BC020204BE"
15 IFPEEK(1545)=49ANDPEEK(1546)=52ANDPEEK(1547)=48ANDPEEK(1548)=53THENTRI=1:PRINT"TRICK-MODE EIN !";:FORZ=1TO100:NEXTZ ELSETRI=0
16 IFTRI=1ANDPEEK(1549)>32THENRU=PEEK(1549)-48
19 CLS:PRINT"LESE DATEN ... 0   /";STR$(WK);
20 RESTORE#:RESTORE#"()fcn",,30
25 READ#A$:GOTO40
30 CLS:PRINT"FINDE KEINE WOERTER !!!":CLEAR:CLS:END
40 RESTORE#"",,90
50 READ#W$(A)
55 IFW$(A)="()ende"THEN90
57 READ#Z$,W(A)
60 A=A+1:LOCATE14,0:PRINTA-1;
70 GOTO40
90 SP$="________________________________"
95 IFINKEY$="."THENCLS:GOTO5200
100 GOSUB4700
102 CLS:PRINT"Glücksrad / ";MID$(STR$(RU),2,1);".RUNDE             ";NM$(1);" beginnt ! Viel Glück !";CHR$(11);
110 MAX=A-1
120 RESTORE2000
130 FORA=1TO80
140 READGR$(A)
150 NEXTA
155 RESTORE2400:FORZ=1TO6:READTP$(Z):NEXTZ
157 IFLOA=1THENRETURN
160 ME$(1)="00000":ME(1)=0
161 ME$(2)="00000"
162 ME$(3)="00000"
180 IFRU=4THENMG(1)=1000:GOTO3000
185 IFRU=5THEN3800
200 IFDM=MAX THEN650
201 DEFCHR$(255)="0000000000"
202 A=INT(RAN#*MAX)+1
205 IFD(A)=1THEN202
207 D(A)=1:DM=DM+1
210 PKT=0:FV=0:D$=W$(A):L=LEN(D$):PMAX=L:BR=0:PKTS=0:ZV=0:ZK=0
212 BS$=".........................."
215 IFRET=1THENRETURN
220 CLS:PRINT"  ";LEFT$(SP$,L);
227 RESTORE#:RESTORE#D$:READ#D$:READ#BR$
230 PRINTCHR$(9);
232 DIMLT(26)
235 FORA=1TOL
237 A$=MID$(D$,A,1):AA=ASC(A$)
240 IFAA<65THENLOCATEA+1,0:PRINTA$;:PMAX=PMAX-1:GOTO245
242 IFAA=65ORAA=69ORAA=73ORAA=79ORAA=85THENLT(AA-64)=1ELSELT(AA-64)=2
245 NEXTA
246 GOSUB4200
247 IFRET=1THENRETURN
250 GOTO1000
252 A$=INPUT$(1,@)
253 AA=ASC(A$)
255 IFAA=14ANDTRI=1THEN800
260 IFAA<65ORAA>91ORPEEK(AA-31)<>46THEN252
263 IFAA=65ORAA=69ORAA=73ORAA=79ORAA=85THENV=-1ELSEV=0
265 IF V XOR VOK THEN 252
270 BS$=LEFT$(BS$,AA-65)+A$+MID$(BS$,AA-63)
275 LOCATE2,1:PRINTBS$;
280 PKT=0
290 FORA=1TOL
300 IFMID$(D$,A,1)=A$THENPKT=PKT+1:LOCATEA+1,0:PRINTA$;
310 NEXTA
312 PKTS=PKTS+PKT
315 IFPKT=0THENGOSUB2200:GOSUB2100:GOTO320
316 IFV=-1THENZV=ZV+1ELSEZK=ZK+1
317 IFVOK=0THENME(PL)=ME(PL)+PKT*E:GOSUB2100
320 IFPKTS=PMAX THENVOK=0:GOTO500
330 GOTO250
400 L$=""
410 FORA=2TOL+1
415 Z=PEEK(A):IFZ=0THENZ=32
420 L$=L$+CHR$(Z)
430 NEXTA
435 IFRIGHT$(L$,1)=" "THENL$=LEFT$(L$,LEN(L$)-1):GOTO435
437 IFSAV=1THENRETURN
440 LOCATE0,0:PRINT"?:";
445 LOCATE0,1:PRINT"                               ";
450 GOSUB1600
452 L3$=L$:L$=""
455 FORA=2TO30
460 L$=L$+CHR$(PEEK(A))
465 NEXTA
467 AA=ASC(RIGHT$(L$,1))
470 IFAA=0ORAA=32THENL$=LEFT$(L$,LEN(L$)-1):GOTO467
472 IFRET=1THENRETURN
475 IFL$=D$THEN500
480 GOTO1920
500 FORZ=1TO500:NEXTZ
501 CLS:ME(PL)=ME(PL)+1000
502 FORA=1TO3:MG(A)=MG(A)+ME(A):NEXTA
505 ZZ=1:GOSUB2100
510 PRINT"    *** ENDE VON RUNDE";RU;"***";
520 RESTORE2500
525 IFRU=3THEN3000
527 IFINKEY$="E"ANDTRI=1THEN570
530 FORA=1TO13
535 READA$,T
537 IFLEFT$(A$,1)="*"THENZ=VAL(MID$(A$,2)):GOSUBZ
540 LOCATE0,1:PRINTA$;
545 FORZ=1TOT:NEXTZ
550 LOCATE0,1:PRINT"                               ";
555 FORZ=1TO500:NEXTZ
560 NEXTA
570 ERASEME,ME$:DIMME(3),ME$(3)
575 RU=RU+1
580 IFRU<=ZPL THENPL=RU ELSEPL=ZPL
585 ME$(1)="00000":ME$(2)="00000":ME$(3)="00000"
590 GOTO200
600 FORA=1TO500:NEXTA
610 CLS:PRINT"  Sie haben das Raetsel leider          NICHT geloest !";
620 A$=INPUT$(1,@)
630 GOTO200
650 CLS:PRINT"FINDE KEINE WEITEREN RAETSEL !":CLEAR:CLS:END
700 DATA 0000000000
710 DATA 0000780000
720 DATA C020780000
730 DATA C0207820C0
740 DATA C2247820C0
750 DATA C2247824C2
800 LOCATE0,0:PRINT"> ";
810 FORZ=1TOL
820 PRINTMID$(D$,Z,1);
830 FORZZ=1TO70:NEXTZZ
840 NEXTZ
845 IFRET=1THENRETURN
850 GOTO500
900 RETURN
901 'GALGEN-MANN (!) *AUS*
902 RESTORE700
905 IFFV>5THEN800
910 FORZ=1TOFV+1
920 READZ$
930 NEXTZ
940 DEFCHR$(255)=Z$
950 RETURN
1000 IFZK=MK THENGOSUB4100
1005 VOK=0:LOCATE0,1:PRINT"          ";
1010 GOSUB2130
1030 LOCATE0,1:PRINT"          ";
1040 LOCATE1,1:PRINTBR$;
1042 A$=INPUT$(1,@)
1043 IFA$="."THENGOSUB5000
1045 IF ASC(A$)=8THEN400
1046 IFA$="E"THEN1800
1047 IF ASC(A$)=14ANDTRI=1THEN800
1048 IFZK=MK THEN1042
1050 IFINKEY$<>""THEN1050
1052 GOSUB1300
1055 A=INT(RAN#*20)+(RU-1)*20:RC=(RU-1)*20+1
1057 PRINTCHR$(11);CHR$(9);
1060 LOCATE0,1:PRINT"          ";
1065 LOCATE4-INT(LEN(GR$(A))/2),1
1070 PRINTGR$(A);
1073 D=D*1.2
1075 FORZ=1TOD:NEXTZ
1077 IFD>300THEN1100
1080 IFA=RC+19THENA=RC ELSEA=A+1
1090 GOTO1060
1100 E$=GR$(A):E=VAL(E$)
1105 IFBON>0THEN2300
1110 IFE$="BANKROTT"THENME(PL)=0:GOSUB2100:GOSUB2200:GOSUB2100:GOTO1030
1120 IFE$="AUSSETZEN"THENGOSUB2200:GOSUB2100:GOTO1030
1130 IFE$="MINUS"THENME(PL)=INT(ME(PL)/2):GOSUB2100:GOTO1030
1140 IFE$="BONUS"THENBON=RU:RU=4:A$=INPUT$(1,@):GOTO1050
1200 GOSUB2100
1201 LOCATE28,1:PRINT">";:LOCATE30,1:PRINT"<";
1202 LOCATE29,1:A$=INPUT$(1,@)
1205 LOCATE0,1:PRINT"  ";BS$;"   ";
1210 GOTO253
1300 DEFCHR$(252)="0000000000"
1310 D=0:X=1:LOCATE0,1:PRINT"         ";
1320 FORA=2TO6
1330 IFINKEY$<>""THEN1500
1340 DEFCHR$(252)=TP$(A)
1350 NEXTA
1360 IFX>7THEN1400
1370 LOCATEX,1:PRINT"‡";
1375 DEFCHR$(252)="0000000000"
1380 PRINTCHR$(252);
1390 IFINKEY$<>""THEN1500
1395 X=X+1:GOTO1320
1400 FORA=5TO1STEP-1
1410 DEFCHR$(252)=TP$(A)
1415 IFINKEY$<>""THEN1500
1420 NEXTA
1430 IFX<2THEN1320
1440 LOCATEX,1:PRINT" ";
1450 DEFCHR$(252)="FFFFFFFFFF"
1460 LOCATEX-1,1:PRINTCHR$(252);
1470 IFINKEY$<>""THEN1500
1485 X=X-1:GOTO1400
1500 D=25-(X*2.5+A*.5)
1510 RETURN
1600 A=1:L2$=L$:T=30:EN=0
1605 LOCATE0,1:PRINT"  Bitte Loesung eingeben :";
1610 IFMID$(L$,A,1)="_"THEN1630
1620 IFA<LEN(L$)THENA=A+1:GOTO1610
1630 IFA<LEN(L$)THENLOCATEA+1,0:PRINT" ";ELSEEN=1
1640 A$=INKEY$
1643 T=T-0.2:LOCATE26,1:PRINTINT(T);
1645 IFT<=0THEN1900
1648 IFA$=""THEN1640
1650 LOCATEA+1,0
1655 AA=ASC(A$)
1660 IFAA>64ANDAA<91THENIFEN=0ORRIGHT$(L$,1)="_"THENPRINTA$;:GOTO1620
1670 IFAA=8THENEN=0:GOTO1700
1680 IFAA=13THEN1695
1690 GOTO1640
1695 LOCATE0,0:PRINT"  ";:LOCATE0,1:PRINT"                               ";:RETURN
1700 IFA<LEN(L$)ORRIGHT$(L$,1)="_"THENLOCATEA+1,0:PRINT"_";
1703 IFA<2THEN1640
1705 Z=A-1
1710 IFMID$(L$,Z,1)="_"THEN1740
1720 IFZ>1THENZ=Z-1:GOTO1710
1730 GOTO1640
1740 LOCATEZ+1,0:PRINT" ";
1745 A=Z:GOTO1640
1800 IFZV=MV THEN1042
1805 IFME(PL)<450THEN1040
1810 ME(PL)=ME(PL)-450
1812 GOSUB2100
1815 LOCATE1,1:PRINT"VOKAL ! ";:FORZ=1TO600:NEXTZ
1820 LOCATE0,1:PRINT"  ";BS$;"   ";
1830 VOK=-1:GOTO252
1840 BEEP:BEEP1:PRINT"ZEILE 1840 !":END
1900 IFRET=1THENTT=1:RETURN
1905 CLS:L3$=L$
1910 PRINT"Die Zeit ist abgelaufen ...";
1915 GOTO1930
1920 CLS:PRINT"Die Loesung ist falsch ...";
1930 GOSUB2200:GOSUB2100
1935 LOCATE1,1:PRINTBR$;
1940 FORA=1TO600:NEXTA
1945 LOCATE0,0:PRINT"                               ";
1950 LOCATE0,0:PRINT"  ";L3$;
1960 GOTO1000
2000 DATA MINUS,350,750,400,700,1000,AUSSETZEN,500,250,750,400,300,BANKROTT,300,1000,500,250,700,350,BONUS
2010 DATA 750,700,2000,AUSSETZEN,500,2000,MINUS,BANKROTT,750,400,1500,300,AUSSETZEN,300,1000,500,250,700,350,BONUS
2020 DATA MINUS,700,2000,AUSSETZEN,500,2500,BANKROTT,750,5000,400,1500,*3,350,AUSSETZEN,1000,500,250,700,400,BANKROTT
2030 DATA 500,1000,2000,*2,250,300,700,1000,500,250,1000,500,*3,700,500,300,*2,250,700,2000
2100 A=PL
2105 Z$=STR$(ME(A))
2110 ME$(A)=MID$(Z$,2,LEN(Z$)-1)
2120 IFLEN(ME$(A))<5THENME$(A)="0"+ME$(A):GOTO2120
2125 IFZZ=1THENZZ=0:GOTO2140
2130 LOCATE10,1:PRINTME$(1);" ";ME$(2);" ";ME$(3);" <";MID$(STR$(PL),2,1);">";
2140 RETURN
2200 IFPL<ZPL THENPL=PL+1ELSEPL=1
2210 RETURN
2300 IFE$="*2"THENME(PL)=ME(PL)*2:GOTO2330
2310 IFE$="*3"THENME(PL)=ME(PL)*3:GOTO2330
2320 ME(PL)=ME(PL)+E
2330 RU=BON:BON=0:GOSUB2100:GOTO1030
2400 DATA 0000000000
2410 DATA FF00000000
2420 DATA FFFF000000
2430 DATA FFFFFF0000
2440 DATA FFFFFFFF00
2450 DATA FFFFFFFFFF
2500 DATA "*2750",200
2502 DATA "  Extra-Bonus dafuer: DM 01000",200
2504 DATA "Der Rundengewinn im Ueberblick:",200
2506 DATA "*2700",200
2508 DATA "*2710",200
2510 DATA "*2720",200
2520 DATA "*2600",500
2522 DATA " ... und die Konto-Staende:",100
2524 DATA "*2800",0
2526 DATA "*2850",100
2528 DATA "Auf dem Rad liegen jetzt u.a.:",100
2530 DATA "*2870",2000
2532 DATA "*2900",200
2600 WE=0
2610 IFME(1)>ME(2)ANDME(1)>ME(3)THENWE=1:GOTO2640
2620 IFME(2)>ME(1)ANDME(2)>ME(3)THENWE=2:GOTO2640
2630 IFME(3)>ME(1)ANDME(3)>ME(2)THENWE=3:GOTO2640
2635 IFME(1)=ME(2)ORME(1)=ME(3)ORME(2)=ME(3)THEN2650
2640 A$="Sieger von Runde"+STR$(RU)+": "+NM$(WE)+" !":GOTO2660
2650 A$="Runde"+STR$(RU)+" ist unentschieden !"
2660 RETURN
2700 A$="Gewinn von "+NM$(1)+": DM "+ME$(1):RETURN
2710 A$="Gewinn von "+NM$(2)+": DM "+ME$(2):RETURN
2720 A$="Gewinn von "+NM$(3)+": DM "+ME$(3):RETURN
2750 A$=NM$(PL)+" hat das Wort erraten !":RETURN
2800 LOCATE0,0:PRINT"                               ";
2805 LOCATE0,0:PRINTNM$(1);:LOCATE10,0:PRINTNM$(2);:LOCATE20,0:PRINTNM$(3);
2810 LOCATE0,1:PRINTMG(1);"DM";:LOCATE10,1:PRINTMG(2);"DM";:LOCATE20,1:PRINTMG(3);"DM";
2820 FORZ=1TO2000:NEXTZ
2830 A$="":LOCATE0,0:PRINT"    *** ENDE VON RUNDE";RU;"***";
2840 RETURN
2850 A$="Es geht weiter mit Runde"+STR$(RU+1)+" !":RETURN
2870 IFRU=1THENA$="1ðBANKR. 2ðPAUSE 1ðBONUS  -2000":RETURN
2880 IFRU=2THENA$="2ðBANKR. 2ðPAUSE 0ðBONUS  -5000":RETURN
2900 A$=NM$(RU+1)+" beginnt. Viel Glueck !":RETURN
3000 FORA=1TO9
3010 READA$,T
3020 IFLEFT$(A$,1)="*"THENZ=VAL(MID$(A$,2)):GOSUBZ
3030 LOCATE0,1:PRINTA$;
3040 FORZ=1TOT:NEXTZ
3050 LOCATE0,1:PRINT"                               ";
3060 FORZ=1TO500:NEXTZ
3070 NEXTA
3080 IFMG(1)>MG(2)ANDMG(1)>MG(3)THENA=1:GOTO3110
3090 IFMG(2)>MG(1)ANDMG(2)>MG(3)THENA=2:GOTO3110
3100 IFMG(3)>MG(2)ANDMG(3)>MG(1)THENA=3:GOTO3110
3101 CLS:PRINT"UNENTSCHIEDEN !!!               Jetzt entscheidet das Los !";
3103 FORZ=1TO3
3104 LOCATE19,0:PRINTNM$(Z);"     ";
3105 IFINKEY$<>""THEN3108
3106 NEXTZ
3107 GOTO3103
3108 A=INT(RAN#*ZPL)+1
3109 LOCATE19,0:PRINTNM$(A);"     ";:FORZ=1TO300:NEXTZ
3110 CLS:PRINT"        ***  FINALE  ***        ";NM$(A);" spielt jetzt im Finale !";CHR$(11);
3120 FORZ=1TO1500:NEXTZ:PL=A
3130 GOSUB4950
3140 CLS:PRINT"       ***  FINALE  ***";
3200 RET=1:GOSUB200
3210 RESTORE#:RESTORE#D$:READ#D$:READ#BR$
3215 LOCATE0,1:PRINT"                               ";
3220 LOCATE0,1:PRINT"Raetsel aus dem Bereich ";BR$;CHR$(11);CHR$(9);
3230 FORZ=1TO1200:NEXTZ
3240 CLS:PRINT" Bitte 5 Konsonanten waehlen:    >     <";
3250 LOCATE2,1:A=1
3260 A$=INPUT$(1)
3265 AA=ASC(A$)
3270 IFAA=8THEN3330
3275 IFAA=65ORAA=69ORAA=73ORAA=79ORAA=85THEN3260
3280 IFAA>64ANDAA<91THEN3300
3290 GOTO3260
3300 PRINTA$;
3310 A=A+1:IFA<6THEN3260
3320 GOTO3380
3330 'BACKSPACE
3340 IFA<2THEN3260
3350 A=A-1
3360 PRINTCHR$(8);CHR$(18);
3370 GOTO3260
3380 K$=""
3385 FORZ=34TO38
3390 K$=K$+CHR$(PEEK(Z))
3395 NEXTZ
3400 FORZ=1TO500:NEXTZ
3410 CLS:PRINT" und jetzt noch einen Vokal ...  > <";
3420 LOCATE2,1:A$=INPUT$(1)
3423 AA=ASC(A$)
3430 IFAA=65ORAA=69ORAA=73ORAA=79ORAA=85THEN3440
3435 GOTO3420
3440 PRINTA$;:K$=K$+A$
3450 FORZ=1TO500:NEXTZ
3500 CLS:PRINT"  ";LEFT$(SP$,L);
3502 RET=1:GOSUB232
3503 FORZ=1TO500:NEXTZ
3505 FORZ=1TO6
3510 A$=MID$(K$,Z,1)
3520 FORA=1TOL
3530 IFMID$(D$,A,1)=A$THENPKT=PKT+1:LOCATEA+1,0:PRINTA$;
3540 NEXTA
3550 FORZZ=1TO200:NEXTZZ
3560 NEXTZ
3570 RET=1:GOSUB400
3575 IFTT=1THENTT=0:LOCATE0,1:PRINT" Die Zeit ist abgelaufen !     ";:FORZ=1TO1000:NEXTZ
3580 IFD$<>L$THEN3700
3600 CLS
3610 FORA=1TO13
3615 PRINT"  GEWONNEN !!!   GEWONNEN !!!     GEWONNEN !!!   GEWONNEN !!!";
3620 FORZ=1TO50:NEXTZ
3625 CLS
3630 FORZ=1TO50:NEXTZ
3635 NEXTA
3637 CLS:PRINT" ... und das ist Ihr Gewinn:";:FORZ=1TO800:NEXTZ
3638 CLS:PRINTW$;:A$=INPUT$(1,@)
3640 CLS:PRINT"       *** SPIELENDE ***            Supergewinn:";W;"DM !!!";
3650 FORZ=1TO1200:NEXTZ
3660 MG(PL)=MG(PL)+W
3670 GOTO3800
3700 RET=1:GOSUB800
3705 RESTORE3790
3710 FORA=1TO7
3715 READA$
3720 LOCATE0,1:PRINT"                               ";
3730 LOCATE16-INT(LEN(A$)/2),1:PRINTA$;
3735 FORZ=1TO300:NEXTZ
3740 NEXTA
3750 FORA=1TO500:NEXTA
3760 GOTO3800
3790 DATA "Sie","haben","das","Raetsel","leider","NICHT","geloest"
3800 CLS:PRINT"Der Endstand:";
3810 FORA=1TO3
3815 LOCATE0,1:PRINT"                               ";
3820 LOCATE0,1:PRINTNM$(A);" :";MG(A);"DM";
3830 FORZ=1TO1200:NEXTZ
3840 NEXTA
3850 IFMG(1)<>0ANDMG(2)<>0ANDMG(3)<>0THEN3880
3860 CLS:PRINT"Ein Gluecksrad-Trostpreis fuer: ";
3870 FORA=1TO3
3873 IFMG(A)=0THENPRINT" ";NM$(A);" ";
3878 NEXTA
3879 FORZ=1TO1500:NEXTZ
3880 CLS:PRINT"        *** CREDITS ***";
3881 FORZ=1TO700:NEXTZ
3882 DEFCHR$(252)="BC020204BE"
3885 A$="Idea: MERV GRIFFIN   written by: FLORIAN CASPAR   executive producer: MERV GRIFFIN ENTERPRISES   produced by: SAT.1   copyright by: FC&co.kg.eN* MAINZ   thanks for all riddles !   Glücksrad V2.5 - eine Produktion von FCNã            (c)1993"
3890 FORA=0TO30
3900 LOCATE31-A,1:PRINTMID$(A$,1,A);
3910 'FORZ=1TO30:NEXTZ
3920 NEXTA
3930 FORA=1TOLEN(A$)-30
3940 LOCATE1,1:PRINTMID$(A$,A,30);
3950 'FORZ=1TO30:NEXTZ
3960 NEXTA
3970 FORA=LEN(A$)-29TOLEN(A$)-17
3980 LOCATE1,1:PRINTMID$(A$,A);" ";CHR$(11);
3990 'FORZ=1TO30:NEXTZ
3995 NEXTA
3997 LOCATE0,1:PRINT"   ";
3998 FORZ=1TO1000:NEXTZ
4000 LOCATE0,0:PRINT"       *** Glücksrad ***          Nocheinmal spielen ?  [J/N]";:RET=0
4010 A$=INPUT$(1,@)
4020 IFA$="J"THEN4060
4030 IFA$="N"THEN4050
4040 GOTO4010
4050 CLS:CLEAR:PRINT"Glücksrad !";:END
4060 CLS:PRINT"Neues Spiel - Neues Glueck !";:FORZ=1TO800:NEXTZ
4070 ERASEME,MG:DIMME(3),MG(3):RU=1:PL=1:GOTO160
4100 LOCATE0,1:PRINT"keine Konsonanten mehr vorhanden";CHR$(11);
4110 A$=INPUT$(1,@)
4120 LOCATE0,1:PRINT"                                ";CHR$(11);
4130 RETURN
4200 MV=0:MK=0
4205 FORZ=1TO26
4210 IFLT(Z)=1THENMV=MV+1
4220 IFLT(Z)=2THENMK=MK+1
4230 NEXTZ
4240 ERASELT
4250 RETURN
4300 DATA 0200000000
4302 DATA 0400000000
4304 DATA 0800000000
4306 DATA 1000000000
4308 DATA 2000000000
4310 DATA 4000000000
4312 DATA 8000000000
4314 DATA 0080000000
4316 DATA 0000800000
4318 DATA 0000008000
4320 DATA 0000000080
4322 DATA 0000000040
4324 DATA 0000000020
4326 DATA 0000000010
4328 DATA 0000000008
4330 DATA 0000000004
4332 DATA 0000000002
4334 DATA 0000000200
4336 DATA 0000020000
4338 DATA 0002000000
4340 DATA 0200000000
4400 DIMA$(21)
4402 DEFCHR$(255)="0000000000"
4403 CLS
4405 FORA=1TO64
4410 PRINTCHR$(255);
4420 NEXTA
4425 IFINKEY$="E"THENRETURN
4430 PRINTCHR$(11);
4440 RESTORE4300
4450 FORA=1TO21
4460 READB$:A$(A)=B$
4480 NEXTA
4482 GOTO4530
4490 FORB=1TO5
4495 FORA=1TO21
4500 DEFCHR$(255)=A$(A)
4510 NEXTA
4520 NEXTB
4525 RETURN
4530 GOSUB4490
4540 LOCATE9,0:PRINT" FC&co.kg.eN* ";
4550 GOSUB4490
4560 LOCATE10,1:PRINT" presents: ";
4570 GOSUB4490
4580 LOCATE10,1
4610 DEFCHR$(252)="BC020204BE"
4620 CLS:PRINT"           Glücksrad            ";
4630 GOSUB4800
4640 LOCATE0,1:PRINT"   written by FLORIAN CASPAR    ";CHR$(11);
4650 GOSUB4800
4660 LOCATE0,1:PRINT"    (c)1993 by FCNã / SAT.1    ";
4670 GOSUB4800
4680 LOCATE7,0:PRINT"***";:LOCATE21,0:PRINT"***";
4685 LOCATE0,1:PRINT"    press any key to start !   ";
4690 A$=INPUT$(1,@)
4695 RETURN
4700 NM$(1)="PLAYER1":NM$(2)="PLAYER2":NM$(3)="PLAYER3"
4701 CLS:PRINT"Enter NOW !";
4702 LOCATE0,1:INPUT"Number of players :";@1;ZPL
4703 PRINTCHR$(11);
4704 IFZPL=0THENCLS:GOTO5210
4705 IFZPL<1ORZPL>3THEN4702
4706 FORZ=1TOZPL
4707 LOCATE0,1:PRINT"                               ";
4710 LOCATE0,1:PRINT"Name of player";Z;":";:INPUT@7;NM$(Z)
4711 PRINTCHR$(11);
4712 IFNM$(Z)=""THENNM$(Z)="PLAYER"+MID$(STR$(Z),2,1)
4715 PRINTCHR$(11);
4720 NEXTZ
4730 RETURN
4800 FORZ=1TO6
4820 LOCATE7,0:PRINT"*";:LOCATE23,0:PRINT"*";
4825 GOSUB4895
4830 LOCATE7,0:PRINT" ";:LOCATE23,0:PRINT" ";
4840 LOCATE8,0:PRINT"*";:LOCATE22,0:PRINT"*";
4845 GOSUB4895
4850 LOCATE8,0:PRINT" ";:LOCATE22,0:PRINT" ";
4860 LOCATE9,0:PRINT"*";:LOCATE21,0:PRINT"*";
4865 GOSUB4895
4870 LOCATE9,0:PRINT" ";:LOCATE21,0:PRINT" ";
4880 NEXTZ
4890 RETURN
4895 FORA=1TO50:NEXTA:RETURN
4900 DATA 13,"GUMMIBAERCHEN UND KAUGUMMIS IM        WERT VON 10.000 DM !",10000
4902 DATA "   EIN EINZIGARTIGES ERLEBNIS:    KREUZ UND QUER DURCH DIE USA",20000
4904 DATA "DAS IST LUXUS PUR: MERCEDES 600  (MIT SERIENMAESSIGEM AIRBAG !)",154000
4906 DATA "FLIEGEN SIE INS EURODISNEY-LAND   MIT 1000 DM TASCHENGELD !",12500
4908 DATA "  NEHMEN SIE TEIL AN DER WELT-  BERUEHMTEN RALLEY PARIS-DAKAR !",15700
4910 DATA " SIE HABEN SOEBEN EINE HYPER-   MODERNE EINBAUKUECHE GEWONNEN !",25000
4912 DATA " SEIEN SIE MIT EINER DAUERKARTE   30 JAHRE GAST BEI MAINZ 05 !",5999
4914 DATA " LERNEN SIE BAYERISCH MIT EINEM  SPRACHKURS IM OBERWIESENTAL !",8900
4916 DATA "WIE WAERE ES JETZT MIT EINEM:    PENTIUM-LABTOP+LASER-DRUCKER",18999
4918 DATA "UNSER SUPERPREIS:               EIN KLAPP-RAD MARKE OLAF",27
4920 DATA " AIR FRANCE FLIEGT SIE 3 MONATE         RUND UM DIE WELT !",30000
4922 DATA "ETWAS FUER ANSPRUCHSVOLLE:      EINE CAMPA FERTIG-VILLA !",110000
4924 DATA "FUER ALLE WERDENDEN MILLIONAERE:      99.999 DM IN BAR !!!",99999
4950 RESTORE4900:READZM
4955 CLS:A=INT(RAN#*ZM)+1
4960 FORZ=1TOA
4970 READW$,W
4980 NEXTZ
4990 PRINT" Sie haben JETZT die Chance auf   einen Gewinn von";W;"DM !";:A$=INPUT$(1,@)
4995 RETURN
5000 'SAVE
5005 A$="":SAV=1:GOSUB400:CLS
5010 INPUT"File to save : ";@4;A$
5020 IFA$=""THENSAV=0:GOTO5140ELSEA$="()GS"+A$
5025 CLS:PRINT"Saving ...";
5030 RESTORE#:RESTORE#A$,,5040
5035 FORZ=1TO4:WRITE#:NEXTZ:RESTORE#"@",,5040
5040 DIMZ$(3)
5050 Z$(1)=STR$(L)+","+STR$(DM)+","+STR$(FV)+","+STR$(MK)+","+STR$(MV)+","+STR$(PL)+","+STR$(RC)+","+STR$(RU)+","+STR$(ZK)+","+STR$(ZV)+","+STR$(MAX)+","+STR$(PKT)+","+STR$(ZPL)+","+STR$(PKTS)+","+STR$(PMAX)+","+D$+","+BR$+","+L$+","+BS$
5060 FORZ=1TO3
5070 Z$(2)=Z$(2)+STR$(ME(Z))+","+STR$(MG(Z))+","+ME$(Z)+","+NM$(Z)+","
5080 NEXTZ
5100 FORZ=1TOWK:Z$(3)=Z$(3)+MID$(STR$(D(Z)),2,1):NEXTZ
5110 WRITE#A$
5120 FORZ=1TO3:WRITE#Z$(Z):NEXTZ
5130 SAV=0:ERASEZ$
5140 GOTO5290
5200 'LOAD
5205 $=INPUT$(1,@)
5210 A$="":INPUT"File to load : ";@4;A$:A$="()GS"+A$
5220 IFA$=""THEN1000
5225 CLS:PRINT"Loading ...";
5230 RESTORE#:RESTORE#A$,,5240
5235 GOTO5250
5240 CLS:PRINT"File not found !";:$=INPUT$(1,@):GOTO100
5250 READ#$,L,DM,FV,MK,MV,PL,RC,RU,ZK,ZV,MAX,PKT,ZPL,PKTS,PMAX,D$,BR$,L$,BS$
5260 FORZ=1TO3:READ#ME(Z),MG(Z),ME$(Z),NM$(Z):NEXTZ
5280 READ#$:FORZ=1TOWK:D(Z)=VAL(MID$($,Z,1)):NEXTZ
5285 LOA=1:GOSUB120:LOA=0
5290 CLS:PRINT"  "+L$;:GOSUB2100:LOCATE1,1:PRINTBR$;:GOTO1042