1 '     Der TERMINator V2.0
2 '       (c)1993 by FCNă
5 DEFCHR$(252)="00C0C00000":DEFCHR$(253)="00C6C60000"
6 DEFCHR$(254)="FF829282FF":DEFCHR$(255)="000A0C0000"
7 CALC$="˙"
8 IFZS=1THENCLEAR:GOTO18
10 CLS:CLEAR:DEFSEG=0
15 PRINT"     Der TERMINator -                      (c)1993 by FCNă";:$=INPUT$(1,@)
18 CLS
100 RESTORE#:RESTORE#"()TERMINator",,105
104 GOTO107
105 INPUT"Programm installieren (J/N) ";A$:IFA$="N"THENTE=1:GOTO107
106 P=PEEK((PEEK(1771)+PEEK(1772)*256)+8)-48:IFP<0ORP>9THENCLS:PRINT"Installation unmoeglich !";:$=INPUT$(1,@):TE=1:GOTO107
107 WRITE#"()TERMINator"+STR$(P):WRITE#"()1":WRITE#"()1n"
108 SCH=-1:RESTORE#:RESTORE#"()CON",,110
109 READ#$:SCH$=MID$($,7,1):NO=VAL(MID$($,8)):IFSCH$<>"-"THENSCH=VAL(SCH$)
110 CLS:PRINT"1†SCHED.‡2†SCHULE‡3†OPT. ‡4†INFO - bitte auswaehlen -      main";
115 IFSCH=-1THENLOCATE9,0:PRINT"-";
117 IFNO=0THENLOCATE18,0:PRINT"-";
118 IFTE=1THENLOCATE0,0:PRINT"-";
120 $=INPUT$(1,@)
130 IF$="1"ANDTE=0THEN300
140 IF$="2"ANDSCH>-1THENZS=1:GOTO#SCH
150 IF$="3"ANDNO>0THENZS=3:GOTO#NO
160 IF$="4"THEN4000
162 IF$="5"ANDTE=0THEN5000
165 IF$=CHR$(8)THENCLS:CLEAR:PRINT"(c)1993";:END
170 GOTO120
300 DIMWT$(7),TP$(14),ML(12),ZT$(8)
305 SP$="                               ":CL$=CHR$(11)+CHR$(31)+CHR$(5)
310 RESTORE60000
320 FORZ=1TO7:READWT$(Z):NEXTZ
330 FORZ=1TO8:READTP$(Z)
331 TP$(Z)=LEFT$(TP$(Z)+"      ",7)
332 NEXTZ
333 FORZ=9TO14:READTP$(Z)
334 TP$(Z)=LEFT$(TP$(Z)+"              ",20)
335 NEXTZ
336 FORZ=1TO12:READML(Z):NEXTZ
337 RESTORE#:RESTORE#"()DATE",,340
338 READ#D$:D$=RIGHT$(D$,8):GOTO345
340 CLS:INPUT"DATUM : ";@8;D$
341 IFD$=""THEN110
342 WRITE#"()DATE"+D$
345 CLS
347 GOSUB3200:GOSUB51100
349 AAD$=D$
350 ERASEDD$:DIMDD$(50)
355 RESTORE#:RESTORE#"()TERMINator"
360 RESTORE#"()1"
370 RESTORE#D$,,375
372 GOTO380
375 AD=0:MD=0:GOTO450
380 READ#TT$
385 IFLEN(TT$)>8THENTT=1
390 Z=1
400 READ#DD$(Z)
410 IFMID$(DD$(Z),2,1)<>"="THENMD=Z-1:AD=1:GOTO450
420 Z=Z+1:GOTO400
450 IFMM=1THENMM=0:AD=MD
455 IFFD>0ANDMD>0THENAD=FD:FI=0:FDD=FD:FD=0
457 IFMI=1THENMI=0:GOSUB52200
460 DP$=LEFT$(WT$(WT)+"      ",10)+"†"+LEFT$(D$,2)+"."+MID$(D$,3,2)+"."+RIGHT$(D$,4)+"‡ ( / ) 00"
462 IFF=1THENF=0:RETURN
465 IFRET=0THENLOCATE0,0:PRINTDP$;
470 IFAD=0THENLOCATE0,1:PRINT" -keine Daten vorhanden-       ";
472 IFRET=1ANDAD=0THENPRINTSP$;
475 IFAD=0THEN$=INPUT$(1,@):Z=ASC($):GOTO560
480 IFRET=1THEN510
485 LOCATE24,0:IFAD=1THENPRINT" ";ELSEPRINT"ä";
490 LOCATE26,0:IFAD=MD THENPRINT" ";ELSEPRINT"ć";
500 IFAD>0THENLOCATE29,0:PRINTRIGHT$("0"+MID$(STR$(AD),2),2);
505 LOCATE0,1:PRINT"                               ";
510 T$=MID$(DD$(AD),15,9)
512 TI$=MID$(DD$(AD),3,11)
515 C$=LEFT$(MID$(DD$(AD),24)+SP$,30)
517 IFC$<>LEFT$(SP$,30)ANDRET=0THENLOCATE0,1:PRINT"ĺ";
518 IFLEFT$(C$,1)="ţ"THENNN=1:NN$=C$:C$=">>> Notiz: "+MID$(NN$,2,8):IFRET=0THENLOCATE0,1:PRINT"ţ";
519 Z$=LEFT$(DD$(AD),1)
520 TI=VAL(Z$)
522 IFTI=0THENTI=ASC(Z$)-55
525 LOCATE1,1
526 IFTI<9THENPRINTTI$;"  ";TP$(TI);" ";T$;
527 IFTI>8THENGOSUB52000
528 IFRET=1THENLOCATE1,2:PRINTC$;
529 IFRET=0ANDTT=1THENGOSUB51200:TT=0:LOCATE0,0:PRINTLEFT$(DP$,21);:IF$<>""THEN531
530 $=INPUT$(1,@)
531 Z=ASC($)
540 IF(Z=30ORZ=253)ANDAD>1THENAD=AD-1:GOTO480
550 IF(Z=31ORZ=13)ANDAD<MD THENAD=AD+1:GOTO480
560 IFZ=14ORZ=4THENPRINT$;:GOTO530
565 IF(Z=30ORZ=253)THENMO$="-":GOSUB50000:MM=1:FDD=0:GOTO350
570 IF(Z=31ORZ=13)THENMO$="+":GOSUB50000:FDD=0:GOTO350
580 IFZ=28THENMO$="+":GOSUB50000:FDD=0:GOTO350
590 IFZ=29THENMO$="-":GOSUB50000:FDD=0:GOTO350
600 IFZ=251THEN670
610 IFZ=15THENA=0:GOTO1200
615 IFZ=2THENN=1:GOTO51400
620 IFZ=6THENN=2:GOTO51400
625 IFZ=46THEN1400
627 IFZ=240THEN4200
630 IFZ=18THEN50900
632 IFZ=17THEN1500
635 IFZ=11THEND$=AAD$:GOSUB3200:GOTO350
640 IFZ=69THEN2600
643 IFZ=43ANDNO>0THENZS=1:GOTO#NO
648 IFZ=45ANDNO>0ANDNN=1THENZS=2:GOTO#NO
650 IFZ=8THEN3900
652 IFZ=12THENZZZ=1:GOTO3900
655 IFZ=252ANDRET=0ANDLEN(TT$)>8THENTT=1:GOTO528
657 IFZ=218ANDAD>0ANDRET=0ANDLEN(TT$)=8THENGOTO51550
660 GOTO530
670 IFRET=1ANDTI<9THEN2200
672 IFRET=1THENRET=4:GOSUB1300:RET=0
675 LOCATE0,1:PRINT" ";
680 LOCATE23,0:FORZ=1TO9
682 PRINT" ";:FORZZ=1TO30:NEXTZZ:NEXTZ
685 DP2$="NEW ENTRY"
690 FORZ=1TO9
695 PRINTCSR23;RIGHT$(DP2$,Z);
700 FORZZ=1TO10:NEXTZZ:NEXTZ
705 LOCATE1,1:X=1:MX=23:MI=1:MA=4:MM=0
706 IFED=1THENGOSUB40150:GOTO720
707 FORZ=1TO4:ZT$(Z)="00":NEXTZ
710 PRINT"00:00-00:00  ---     _________";
720 ZX=1:ZY=1:ZL=2:GOSUB40000
722 IFED=0THENY=0
725 ZT=VAL(ZT$(X))
727 LOCATEZX,ZY:PRINTZT$(X);
730 IF$=CHR$(30)THENIFZT>MM THENZT=ZT-1:GOTO750ELSEZT=MX:GOTO750
740 IF$=CHR$(31)THENIFZT<MX THENZT=ZT+1:GOTO750ELSEZT=MM:GOTO750
745 GOTO760
750 ZT$(X)=RIGHT$("000"+MID$(STR$(ZT),2),ZL):GOSUB40000:GOTO725
760 IF$=CHR$(29)ANDX>MI THENX=X-1:ZX=ZX-3:GOSUB39000:GOTO725
770 IF$=CHR$(28)ANDX<MA THENX=X+1:ZX=ZX+3:GOSUB39000:GOTO725
780 IF$=CHR$(28)OR$=CHR$(13)THEN800
785 IF$=CHR$(8)ANDRET=0THENLOCATE0,1:PRINTSP$;:GOTO1360
790 GOSUB40000:GOTO725
800 IFRET=1THENRETURN
802 ZX=14:ZL=7:X=5
805 IFY=0THENZT$(5)="---":Y=1
807 GOSUB40000
810 LOCATEZX,ZY:PRINTZT$(5);
815 IF$=CHR$(30)ANDY>1THENY=Y-1:ZT$(5)=TP$(Y):GOSUB40000:GOTO810
820 IF$=CHR$(31)ANDY<8THENY=Y+1:ZT$(5)=TP$(Y):GOSUB40000:GOTO810
830 IF$=CHR$(29)THENX=4:ZX=10:ZL=2:MX=59:GOSUB40000:GOTO725
840 IF$=CHR$(13)THEN850
842 IF$=CHR$(8)THENLOCATE0,1:PRINTSP$;:RET=0:GOTO1360
845 GOSUB40000:GOTO810
850 IFED=0THENLOCATE22,1:PRINT"         ";
855 LOCATE22,1:INPUT"";@9;T$
860 IFED=0THENLOCATE0,0
865 T$=LEFT$(T$+"         ",9)
867 IFED=1THEN920
870 FORZ=8TO0STEP-1
875 LOCATE31-Z,0:PRINT" ";MID$(DP2$,1,Z);
880 NEXTZ
885 IFSUB=5THENRETURN
890 DP2$=LEFT$(DP$,22)
900 FORZ=21TO0STEP-1
910 PRINTCSR0;RIGHT$(DP2$,Z);" ";:NEXTZ
915 IFRET=1THENRETURN
920 LOCATE0,2:INPUT">";@30;C$
930 LOCATE0,1:LOCATE0,2:PRINTSP$;
933 IFVAL(ZT$(3))=0ANDVAL(ZT$(4))=0THENLOCATE0,2:INPUT" 2. Zeit loeschen (J/N) ? ";@1;L$ELSEL$="N"
934 LOCATE0,1
935 IFL$=""THENL$="J"
937 IFL$<>"J"ANDL$<>"N"THEN933
938 IFED=1THENGOSUB2300
940 RE=0:LOCATE0,2:PRINT" Saving ...                   ";
942 IFED=1THENGOSUB40180
945 IFAD=0THENVD=1:AD=1:MD=1:GOTO1035
950 FORZ=1TOMD
960 IFVAL(MID$(DD$(Z),3,2))<VAL(ZT$(1))THEN970
965 IFVAL(MID$(DD$(Z),3,2))>VAL(ZT$(1))ORVAL(MID$(DD$(Z),6,2))>VAL(ZT$(2)THENVD=Z:GOTO1000
970 NEXTZ
980 VD=Z
1000 MD=MD+1
1010 FORZ=MD TOVD+1STEP-1
1020 DD$(Z)=DD$(Z-1)
1030 NEXTZ
1035 DD$(VD)=RIGHT$(STR$(Y),1)+"="+ZT$(1)+":"+ZT$(2)
1038 IFL$="N"THENDD$(VD)=DD$(VD)+"-"+ZT$(3)+":"+ZT$(4)ELSEDD$(VD)=DD$(VD)+"      "
1040 DD$(VD)=DD$(VD)+"="+T$+C$
1042 GOSUB52200
1045 RESTORE#:RESTORE#"()1"
1050 RESTORE#D$,,1100
1055 READ#$
1060 WRITE#
1070 READ#$
1080 IFMID$($,2,1)<>"="THEN1100
1090 GOTO1045
1100 RESTORE#:RESTORE#"()1n":WRITE#
1101 RESTORE#:RESTORE#D$,,1105
1102 WRITE#
1105 RESTORE#:RESTORE#"@",,1110
1110 WRITE#D$+MID$(TT$,9)
1120 FORZ=1TOMD
1130 WRITE#DD$(Z)
1140 NEXTZ
1150 WRITE#"()1n"
1160 AD=VD:RET=0:TT$=D$
1170 LOCATE0,2:PRINTCHR$(5);
1180 IFED=1THENED=0:AD=VD:RET=1:GOTO470
1190 GOTO1300
1200 ' AUFKLAPPEN
1202 IFRET=1THEN1300
1203 LOCATE0,1:PRINT" ";
1205 DP2$=""
1210 FORZ=23TO30
1220 DP2$=DP2$+CHR$(PEEK(Z))
1230 NEXTZ
1240 RET=1:GOSUB870
1245 IFSUB=5THENDP2$=D$+" ":GOTO1370
1247 IFA=1ORFXSN=1THENRETURN
1250 LOCATE1,2:PRINTC$;
1260 GOTO530
1300 ' ZUKLAPPEN
1310 LOCATE0,2:PRINTCHR$(2);"                               ";
1315 DP3$=LEFT$(DP$,23)
1320 FORZ=0TO23
1330 PRINTCHR$(11);RIGHT$(DP3$,Z);
1340 NEXTZ
1350 IFRET=3THENRET=0:GOTO685
1360 IFED=1THENED=0:RET=1:GOTO470
1365 DP2$="( / ) 00 "
1370 FORZ=31TO23STEP-1
1380 LOCATEZ,0:PRINTMID$(DP2$,1,32-Z);
1390 FORZZ=1TO10:NEXTZZ
1395 NEXTZ
1396 POKE31,0
1397 IFRET=4ORSUB=5THENRETURN
1398 RET=0:GOTO470
1400 'JUMP
1405 IFRET=1THENRET=4:GOSUB1300
1410 ZX=11:ZY=0:ZL=2:MM=1:MX=31:X=6:MI=6:MA=8:RET=1
1420 ZT$(6)=LEFT$(D$,2):ZT$(7)=MID$(D$,3,2):ZT$(8)=RIGHT$(D$,4):GOSUB725:RET=0
1425 D$="    "+ZT$(8):GOSUB51100
1430 IFVAL(ZT$(6))>ML(VAL(ZT$(7)))THENZT$(6)="01"
1440 D$=ZT$(6)+ZT$(7)+ZT$(8)
1445 MM=0
1447 GOSUB3200
1450 GOTO350
1500 ' SUCH-SUCH
1510 IFRET=1THENRET=4:GOSUB1300
1515 SUB=0:FZ=0:IZ=0:FD=0:FI=0
1520 GOSUB50300:GOSUB50500
1525 MD$=D$
1530 LOCATE1,1:PRINT"Suchen ab (0=HEUTE) : ";SD$;
1532 LOCATE23,1:INPUT"";@8;SD$
1535 S$=SD$
1540 PRINTCHR$(11);
1550 IFS$=""ORS$="0"THENS$=D$:SD$=S$
1560 A=VAL(LEFT$(S$,2))
1570 B=VAL(MID$(S$,3,2))
1580 C=VAL(RIGHT$(S$,4))
1590 IFC<1901ORC>2099ORB<1ORB>12THEN1530
1600 IFA<1ORA>ML(B)THEN1530
1605 POKE31,0
1607 LOCATE11,0:PRINTLEFT$(S$,2);".";MID$(S$,3,2);".";RIGHT$(S$,4);
1610 PRINTCL$;
1615 D$=S$
1620 LOCATE0,1:PRINT"nach> 1†TERMIN 2†ZEIT 3†ART :";MO;CHR$(11);
1622 LOCATE30,1:INPUT"";@1;MO
1625 PRINTCL$;
1630 IFMO<1ORMO>3THEN1610
1640 MO$="+"
1642 MWT=WT:SM=1
1645 IFMO=1THENINPUT" Termin: ";@9;S$:PRINTCL$;:IFS$=""THEN50600ELSES=15:L=9:S$=LEFT$(S$+SP$,9)
1650 IFMO=2THENINPUT" Anfangszeit: ";@5;S$:PRINTCL$;:IFS$=""THEN50600ELSES=3:L=5
1660 IFMO=3THENINPUT" Art-Code: ";@2;S$:PRINTCL$;:IFS$=""THEN50600ELSEGOSUB50280:S=1:L=1
1665 SS$=S$
1670 GOSUB50850
1680 SUB=5:GOSUB1205:SUB=0
1700 'MAIN SUCH
1710 RESTORE#:RESTORE#"()1"
1720 RESTORE#D$,,1780
1730 READ#$
1740 READ#Z$
1750 IFMID$(Z$,2,1)<>"="THEN1780
1760 IFMID$(Z$,S,L)=S$THEN1950
1770 GOTO1740
1780 GOSUB50000:FZ=0:IZ=0
1790 LOCATE23,0:PRINTD$;
1795 IFINKEY$=""THEN1710
1800 'SUCH STOP
1805 SM=0:IFFO=1THENFO=0:FI=1
1810 PRINTLC$;" Suche abbgebrochen !          ";:WT=MWT
1820 D$=MD$:DP3$=LEFT$(D$,2)+"."+MID$(D$,3,2)+"."+RIGHT$(D$,4)
1830 FORZ=0TO10
1840 LOCATE11,0
1850 PRINTRIGHT$(DP3$,Z);
1860 FORZZ=1TO30:NEXTZZ:NEXTZ
1870 FORZ=23TO30
1880 LOCATEZ,0:PRINT" ";
1890 FORZZ=1TO30:NEXTZZ:NEXTZ
1900 FD=FDD:RET=4:GOSUB1360:RET=0
1905 GOSUB3200
1910 GOTO50600
1950 ' FOUND !
1960 LOCATE0,1:FOU=1
1970 FORZ=1TO31
1980 PRINTCHR$(17);
1990 NEXTZ
2000 DP2$=" 1†Zeigen 2†Merken 3†Weiter : 1"
2005 LOCATE0,0:PRINT" OBJEKT:  ";
2010 FORZ=1TO31
2020 LOCATE0,1:PRINTRIGHT$(DP2$,Z);
2030 NEXTZ
2040 LOCATE30,1:INPUT"";@1;A
2045 PRINTCHR$(11);
2050 IFA<1ORA>3THEN2040
2060 LOCATE0,1
2070 FORZ=1TO31
2080 PRINTCHR$(17);
2090 NEXTZ
2095 LOCATE0,0:PRINT"SUCH-MODE ";
2100 IFA=1THENSM=0:FO=1:RET=0:WT=MWT:MD$=D$:GOSUB51000:FI=1:FD=FZ:GOSUB3200:GOTO350
2110 IFA=2THENFO=1:MWT=WT:MD$=D$:GOSUB50850:F=1:GOSUB350:GOSUB51000:GOSUB50800:FDD=FZ:FD=FZ:GOTO1740
2120 IFA=3THENGOSUB51000:IZ=FZ:GOSUB50850:GOTO1740
2130 GOTO2040
2200 'EDIT
2210 A$=DD$(AD):ED=1:RET=0
2220 ZT$(1)=MID$(A$,3,2)
2230 ZT$(2)=MID$(A$,6,2)
2240 ZT$(3)=MID$(A$,9,2)
2250 IFZT$(3)="  "THENZT$(3)="00"
2260 ZT$(4)=MID$(A$,12,2)
2270 IFZT$(4)="  "THENZT$(4)="00"
2280 Y=VAL(LEFT$(A$,1))
2290 ZT$(5)=TP$(Y)
2295 GOTO705
2299 'EDIT SUB DATUM AENDERN
2300 LOCATE0,2:PRINT" Datum eingeben: ";D$;"      ";
2310 LOCATE17,2:INPUT"";@8;N$
2320 LOCATE0,1
2325 IFD$=N$THENRETURN
2330 GOSUB2400
2335 D$=N$
2337 GOSUB3200
2340 RESTORE#:RESTORE#"()1":RESTORE#D$,,2345
2342 GOTO2350
2345 TT$=D$
2350 F=1:GOSUB350:GOSUB3200
2360 ED=0:RETURN
2399 'DELETE SOURCE SUB
2400 LOCATE0,2:PRINTSP$;CHR$(2);" Original loeschen (J/N) ? ";
2410 INPUT"";@1;Z$
2420 LOCATE0,1
2430 IFZ$="N"THENRETURN
2435 Z=1
2440 RESTORE#:RESTORE#"()1":RESTORE#D$
2450 RESTORE#DD$(AD)
2460 READ#Z$
2470 IFZ$<>DD$(AD)THENZ=Z+1:GOTO2450
2480 RESTORE#:RESTORE#"()1":RESTORE#D$
2490 FORZZ=1TOZ
2500 RESTORE#DD$(AD)
2510 NEXTZZ
2520 WRITE#
2530 RETURN
2599 'DEL/COPY MENU
2600 IFRET=1THENRET=4:GOSUB1300
2605 DP3$=" (1†DEL 2†DEL AUT. 3†COPY AUT.)"
2610 GOSUB51300
2615 IFAD=0THENLOCATE2,1:PRINT"-";
2620 $=INPUT$(1,@)
2630 IF$="E"THEN465
2640 IF$="1"ANDAD>0THEN2700
2650 IF$="2"THEN2800
2660 IF$="3"THEN3000
2670 GOTO2620
2699 'DEL AKTUELL
2700 DP3$=" Akt. Date loeschen (J/N) ?":GOSUB51300
2710 LOCATE28,1:INPUT"";@1;Z$
2715 PRINTCHR$(11);
2720 IFZ$="N"THEN465
2730 GOSUB2435:MI=1:RE=0
2740 IFMD=1THENRESTORE#:RESTORE#"()1":RESTORE#D$:WRITE#
2750 GOTO350
2799 'DELETE FROM-TO
2800 Z$="DELETING":F$=D$
2810 GOSUB50310
2820 DP3$=" Loeschen von : "
2830 GOSUB51300
2840 LOCATE16,1:INPUT"";@8;Z$
2850 PRINTCHR$(11);
2860 IFLEN(Z$)<8THENGOSUB50600:GOTO465
2870 A$=D$:LOCATE1,1:PRINT"Loeschen bis : ";D$;:LOCATE16,1:INPUT"";@8;D$
2880 PRINTCHR$(11);
2885 RE=0:SM=1:MO$="+":GOSUB50000:E$=D$:D$=Z$
2890 DP3$=" Deleting now till "+A$+" !!"
2900 GOSUB51300:Z=0:DE=1
2910 LOCATE23,0:PRINTD$;
2915 IFINKEY$<>""THEND$=F$:GOTO2990
2917 RESTORE#:RESTORE#"()1":RESTORE#D$,,2950
2920 IFZ=2THENWRITE#:GOTO2945ELSEREAD#$
2925 IFZ=1THENWRITE#:Z=0:GOTO2910ELSEREAD#$
2930 IFMID$($,2,1)="="THENZ=1:GOTO2910
2940 Z=2:GOTO2910
2945 GOSUB52200
2950 GOSUB50000:Z=0
2970 IFD$=E$THEN2985
2980 GOTO2910
2985 SM=0:D$=F$:GOSUB50000
2990 SM=0:DE=0:GOSUB50500:GOSUB50600:GOSUB3200:GOTO350
2999 'COPY-AUT.
3000 DP3$=" Kopier-Automatik - Sicher ? "
3010 GOSUB51300
3020 LOCATE29,1:INPUT"";@1;Z$
3030 PRINTCHR$(11);
3040 IFZ$="N"THENGOSUB50500:GOTO465
3050 Z$="AUT.-COPY ":C$=D$
3060 GOSUB50310
3070 DP3$=" Kopieren von : 0101"+RIGHT$(D$,4)
3080 GOSUB51300:E$=D$
3090 LOCATE16,1:INPUT"";@8;D$
3095 PRINTCHR$(11);
3100 LOCATE1,1:PRINT"Kopieren bis : ";E$;:LOCATE16,1:INPUT"";@8;E$:PRINTCHR$(11);
3105 LOCATE0,1:PRINTSP$;
3110 LOCATE1,1:INPUT"Kopieren Typ Nr. : 8"+CHR$(29);@2;A:A$=RIGHT$(HEX$(A),1)
3120 PRINTCHR$(11);
3125 LOCATE0,1:PRINTSP$;
3130 LOCATE1,1:PRINT"Kopieren in Jahr :";STR$(VAL(RIGHT$(D$,4))+1);:LOCATE20,1:INPUT@4;B$
3140 PRINTCHR$(11);
3142 GOSUB50500:LOCATE0,1:PRINT" Copying now ...  (EXE†Abbruch)";
3145 GOTO3300
3150 ' !ABBRUCH!
3160 SM=0:RET=0:D$=C$:GOSUB50600:GOSUB50500:GOTO465
3199 'WT-ERMITTLUNG !!!
3200 A=VAL(LEFT$(D$,2))
3210 B=VAL(MID$(D$,3,2))
3220 C=VAL(RIGHT$(D$,4))
3230 IFB<3THENA=A+B:IFC MOD4<>0ORC MOD100=0ANDC MOD400<>0THENA=A+1
3240 Z=INT(C*365.25)-INT((13-B)*30.6+.5)+A:WT=(Z-INT(Z/7)*7)+1
3250 RETURN
3300 SUB=5:GOSUB870:RET=4:SM=1:MO$="+":DP2$=D$+" ":GOSUB1370
3310 X=0:IFINKEY$<>""THENSUB=5:GOSUB1365:SUB=0:GOTO3160
3315 RESTORE#:RESTORE#"()1"
3320 RESTORE#D$,,3360:READ#$
3330 X=X+1:READ#$:IFMID$($,2,1)<>"="THEN3360
3340 IFLEFT$($,1)=A$THENGOSUB3400
3350 GOTO3330
3360 IFD$<>E$THENGOSUB50000:LOCATE23,0:PRINTD$;:GOTO3310
3370 LOCATE0,1:PRINT" Operation beendet !!!         ";:GOSUB1365:GOTO3160
3400 Z$=LEFT$(D$,4)+B$
3410 Z=1:RESTORE#:RESTORE#"()1":RESTORE#Z$,,3440:READ#DD$(1):Z=2
3420 READ#DD$(Z):IFMID$(DD$(Z),2,1)<>"="THEN3440
3430 Z=Z+1:GOTO3420
3440 RESTORE#"@",,3450
3450 WRITE#Z$
3452 $=A$+"=00:00      ="+MID$($,15):WRITE#$
3455 FORZZ=2TOZ-1
3460 WRITE#DD$(ZZ)
3470 NEXTZZ:WRITE#"()1n"
3480 RESTORE#:RESTORE#"()1":RESTORE#Z$:FORZZ=1TOZ-1:WRITE#:NEXTZZ
3490 RESTORE#:RESTORE#"()1n":WRITE#
3495 RESTORE#:RESTORE#"()1":RESTORE#D$:READ#$:FORZ=1TOX:READ#$:NEXTZ:RETURN
3899 'ENDE
3900 IFRET=1THENRET=4:GOSUB1300
3902 IFZZZ<>1THEN3910
3905 RESTORE#:RESTORE#"()DATE",,3907
3907 WRITE#"()DATE"+D$
3910 GOSUB50500:A=1:GOSUB1200:FORZ=1TO200:NEXTZ:CLEAR:ZS=1:GOTO5
3999 'SYS-MENU
4000 CLS
4010 PRINT"        Der TERMINator";
4015 FORZ=1TO500:NEXTZ
4020 Z$="          Version 2.0":P1=1:P2=0:GOSUB51700
4030 Z$="  Idee und Realisation:  ":P1=1:P2=0:GOSUB51600
4040 Z$="         FLORIAN CASPAR   ":P1=1:P2=0:GOSUB51700
4050 Z$=" Kalender-Routine von:":P1=0:P2=1:GOSUB51700
4060 Z$="         R.G.S.       ":P1=1:P2=0:GOSUB51700
4070 Z$=" Der TERMINator -     ":P1=0:P2=1:GOSUB51700
4080 Z$=" Eine Produktion von  ":P1=0:P2=0:GOSUB51600
4090 Z$="   FC&co.kg.eN* MAINZ  /  FCNă ":P1=1:P2=0:GOSUB51700
4100 Z$=" released in 7/'93 by:":P1=0:P2=1:GOSUB 51700
4110 Z$="      Florian Caspar Networks":P1=1:P2=0:GOSUB51700
4120 Z$=" Programmiert in":P1=0:P2=1:GOSUB51700
4130 Z$="  La Faute sur mer, Frankreich":P1=1:P2=0:GOSUB51700
4140 Z$=" (c)1993":P1=0:P2=1:GOSUB51700
4143 Z$=" Programm-Erweiterungen:":P1=0:P2=0:GOSUB51600
4145 Z$=" SCHOOL-TERMINator -":P1=0:P2=0:GOSUB51600
4147 Z$=" Hausaufgaben/Noten/Stundenplan":P1=1:P2=1:GOSUB51600
4150 Z$=" TERMINator-Manager (Planung) -":P1=1:P2=0:GOSUB51600
4152 Z$=" Verschiedene Daten verknuepfen":P1=1:P2=1:GOSUB51600
4153 Z$=" ":P1=1:P2=1:GOSUB51600
4155 Z$="Freier Speicher:"+STR$(FRE1)+" Bytes":P1=0:P2=0:GOSUB51600
4160 Z$=" Variablen-Bereich:"+STR$(FRE2)+" Bytes":P1=1:P2=1:GOSUB51600
4170 FORZ=1TO300:NEXTZ
4180 Z$=" ":P1=0:P2=0:GOSUB51600
4190 Z$=" ":P1=1:P2=1:GOSUB51600
4195 CLS:GOTO110
4199 'KAL-FUNKT.
4200 GOSUB3200:GOSUB50500:FXSN=1:GOSUB1200:FXSN=0
4205 IFRE=1THENA=VAL(LEFT$(D$,2)):GOTO4392
4210 W$="":FORZ=1TO6:W$=W$+" Sa  So  Mo  Di  Mi  Do  Fr ":NEXTZ
4220 A=1:GOSUB3230:A=VAL(LEFT$(D$,2)):L=ML(B)
4230 W$=MID$(W$,(4*WT)-3,4*L)
4260 I$="  ":FORZ=1TOL
4270 I$=I$+RIGHT$("   "+STR$(Z),2)+"  "
4280 NEXTZ
4290 MA$=">"+CHR$(28)+CHR$(28)+"<":RE=1
4300 CLS:PRINT" Calc ...";
4310 Z$=MID$(STR$(C),4,2)
4320 P$=" ü.ý"
4330 RESTORE#:RESTORE#"()1"
4340 M$="()"+RIGHT$(D$,6):RESTORE#M$,,4990:READ#$
4350 T$="":FORZ=1TOL
4370 ZZ=VAL(MID$($,Z+8,1))+1
4380 T$=T$+CHR$(28)+CHR$(28)+CHR$(28)+MID$(P$,ZZ,1)
4390 NEXTZ
4392 X=A*4-3:Y=3
4395 CLS:LOCATE0,0:PRINTMID$(D$,3,2);:LOCATE0,1:PRINTRIGHT$(D$,2);
4400 LOCATE3,0:PRINTMID$(W$,X,28);:LOCATE2,1:PRINTMID$(I$,X,28);:LOCATE3,1:PRINTMID$(T$,X,28);
4420 LOCATEY,0:PRINTMA$;
4430 Z=ASC(INPUT$(1,@))
4440 IFZ=13THEND$=RIGHT$("0"+MID$(STR$((X+Y)/4),2),2)+RIGHT$(D$,6):GOSUB3200:RET=0:GOTO350
4450 IFZ=28ANDX+Y<L*4-3THENA=A+1:IFY<24THENY=Y+4:GOTO4400ELSEX=X+4:GOTO4400
4460 IFZ=29ANDX>1THENA=A-1:IFY>3THENY=Y-4:GOTO4400ELSEX=X-4:GOTO4400
4462 IFZ=8THENRET=0:CLS:GOTO350
4465 IFZ<28ORZ>29THEN4430
4470 RE=1:IFZ=28THENB=B+1:A=1:IFB=13THENC=C+1:B=1:D$="0101"+RIGHT$(STR$(C),4):GOTO4210ELSED$="01"+RIGHT$("0"+MID$(STR$(B),2),2)+RIGHT$(D$,4):GOTO4210
4480 IFZ=29THENB=B-1:IFB=0THENC=C-1:A=31:B=12:D$="3112"+RIGHT$(STR$(C),4):GOTO4210ELSEA=ML(B):D$=RIGHT$("0"+MID$(STR$(A),2),2)+RIGHT$("0"+MID$(STR$(B),2),2)+RIGHT$(D$,4):GOTO4210
4990 $=M$+"0000000000000000000000000000000":WRITE#$:GOTO4350
4999 'NEW
5000 CLS:PRINT"!!! ACHTUNG !!!                 Alles loeschen ? ";
5010 INPUT@1;Z$:CLS:IFZ$<>"J"THEN110ELSERESTORE#
5020 RESTORE#"()TERMINator"
5040 FORZ=1TO200:WRITE#:NEXTZ
5050 CLS:CLEAR:PRINT"ALLE DATEN GELOESCHT !":CLS:PRINT"(c)1993";:END
38999 ' SUB INPUT-STELLE
39000 IFX/2=INT(X/2)ANDX<6THENMX=59:GOTO40000
39005 IFX<6THENMX=23:GOTO40000
39010 IFX=6THENMX=31
39020 IFX=7THENMM=1:MX=12:ZL=2
39030 IFX=8THENMM=1901:MX=2099:ZL=4
39040 GOTO40000
39999 ' SUB INPUT
40000 ZS$=LEFT$("                       ",ZL)
40010 LOCATEZX,ZY
40020 PRINTZT$(X);
40030 $=INKEY$:IF$<>""THENRETURN
40040 FORZ=1TO10:NEXTZ
40050 $=INKEY$:IF$<>""THENRETURN
40060 FORZ=1TO10:NEXTZ
40070 $=INKEY$:IF$<>""THENRETURN
40080 LOCATEZX,ZY:PRINTZS$;
40090 $=INKEY$:IF$<>""THENRETURN
40100 FORZ=1TO10:NEXTZ
40110 $=INKEY$:IF$<>""THENRETURN
40120 FORZ=1TO10:NEXTZ
40130 $=INKEY$:IF$<>""THENRETURN
40140 GOTO40010
40149 ' EDIT SUB
40150 LOCATE1,1:PRINTZT$(1);":";ZT$(2);"-";ZT$(3);":";ZT$(4);"  ";ZT$(5);" ";T$;
40160 RETURN
40179 'EDIT DD$(AD) CLEAR SUB
40180 FORZ=AD TOMD
40185 DD$(Z)=DD$(Z+1)
40190 NEXTZ
40192 MD=MD-1
40195 RETURN
50000 ' SUB DATUM
50010 T1=VAL(LEFT$(D$,2))
50020 T2=VAL(MID$(D$,3,2))
50030 T3=VAL(RIGHT$(D$,4))
50035 IFMO$="+"THENGOSUB50100:GOTO50070
50037 IFSM=0THENGOSUB50200
50040 IFT1>1THENT1=T1-1:GOTO50070
50050 RE=0:IFT2>1THENT2=T2-1:T1=ML(T2):GOTO50070
50060 T3=T3-1:T2=12:T1=31:D$=RIGHT$("      "+STR$(T3),8):GOSUB51100
50070 D$=RIGHT$("0"+MID$(STR$(T1),2),2)+RIGHT$("0"+MID$(STR$(T2),2),2)+RIGHT$("0"+MID$(STR$(T3),2),4)
50080 RETURN
50100 ' SUB +
50105 IFSM=0THENGOSUB50250
50110 IFT1<ML(T2)THENT1=T1+1:RETURN
50120 IFT2<12THENT2=T2+1:T1=1:RETURN
50130 T3=T3+1:T2=1:T1=1:D$=RIGHT$("      "+STR$(T3),8):GOSUB51100:RETURN
50199 ' SUB WO-TAG -/+
50200 IFWT>1THENWT=WT-1:RETURN ELSEWT=7:RETURN
50250 IFWT<7THENWT=WT+1:RETURN ELSEWT=1:RETURN
50280 IFVAL(S$)>9THENS$=CHR$(VAL(S$)+55)
50290 RETURN
50299 'SUCH-IN
50300 Z$="SUCH-MODE "
50310 LOCATE0,0
50320 FORZ=1TO10
50330 PRINTCHR$(17);
50340 NEXTZ
50350 FORZ=1TO10
50360 PRINTCHR$(18);
50370 NEXTZ
50380 FORZ=0TO10
50390 LOCATE0,0:PRINTRIGHT$(Z$,Z);
50400 NEXTZ
50410 RETURN
50499 'LEER Z.2
50500 LOCATE0,1
50510 FORZ=1TO31
50520 PRINT" ";
50530 NEXTZ
50540 RETURN
50599 'SUCH OUT
50600 LOCATE31,0:PRINT" ";
50605 PRINTCHR$(11);
50610 FORZ=1TO10
50620 PRINTCHR$(18);
50630 NEXTZ
50640 DP3$=LEFT$(WT$(WT)+"        ",10)
50650 FORZ=0TO10
50660 PRINTCHR$(11);RIGHT$(DP3$,Z);
50670 NEXTZ
50680 LOCATE10,0
50690 FORZ=1TO10
50700 PRINTCHR$(17);
50710 NEXTZ
50720 GOTO350
50799 'FIXIEREN SUCH SUB
50800 Z=1
50810 IFMID$(DD$(Z),S,L)=S$ANDIZ<Z THENIZ=Z:RETURN
50820 IFZ<50THENZ=Z+1:GOTO50810ELSEIZ=0:RETURN
50849 'CONT SUCH FIXIER SUB
50850 LOCATE23,0:PRINTD$;:LOCATE0,1:PRINT" Searching ...  (EXE†Abbruch)  ";:RETURN
50899 'SUCH CONT
50900 SM=1:IFSS$=""THEN1500
50905 IFRET=1THENRET=4:GOSUB1300:RET=0
50910 S$=SS$:MD$=D$:MO$="+":MWT=WT
50920 GOSUB50300:GOSUB50500:GOSUB50850
50930 IFFDD>0THENGOSUB50800:IZ=IZ-1:GOSUB51000:IZ=IZ+1ELSEIFAD=0THENFZ=0:IZ=0:GOTO1700ELSEFDD=AD:IZ=AD:FZ=AD:GOSUB50950
50940 GOTO1740
50950 RESTORE#:RESTORE#"()1":RESTORE#D$:FORZ=0TOAD:READ#$:NEXTZ:RETURN
50999 ' FIXIER DURCH READ#
51000 RESTORE#:RESTORE#"()1"
51010 RESTORE#D$,,1780:READ#$
51020 FZ=1
51030 READ#$
51040 IFMID$($,2,1)<>"="THENMO$="+":GOSUB50000:LOCATE23,0:PRINTD$;:GOTO1710
51050 IFMID$($,S,L)=S$ANDFZ>IZ THENRETURN
51060 FZ=FZ+1:GOTO51030
51099 'SCHALTJAHR PRUEF SUB
51100 IFVAL(RIGHT$(D$,4))/4=INT(VAL(RIGHT$(D$,4))/4)THENML(2)=29ELSEML(2)=28
51110 RETURN
51199 'ABSOLUTER TAGES-TITEL$
51200 T$=LEFT$(MID$(TT$,9)+"                     ",21)
51210 LOCATE0,0:PRINTT$;
51220 FORZ=1TO80
51230 $=INKEY$:IF$=CHR$(218)THENGOSUB51500
51235 IF$<>""THENRETURN
51240 NEXTZ
51250 RETURN
51299 '2. ZEILE OUT-IN
51300 LOCATE0,1
51310 FORZ=1TO31
51320 PRINTCHR$(17);
51330 NEXTZ
51340 FORZ=1TOLEN(DP3$)
51350 LOCATE0,1:PRINTRIGHT$(DP3$,Z);
51360 NEXTZ
51370 RETURN
51399 'LAST/NEXT
51400 SM=1:IFN=1THENDP3$=" Searching for LAST ...":MO$="-"
51405 IFN=2THENDP3$=" Searching for NEXT ...":MO$="+"
51410 GOSUB51300
51415 ZD$=D$:GOSUB50000
51420 RESTORE#:RESTORE#"()1"
51425 IFINKEY$<>""THEN51480
51430 LOCATE23,0:PRINTD$;
51440 RESTORE#D$,,51460
51450 SM=0:GOSUB3200:GOTO350
51460 GOSUB50000
51470 GOTO51420
51480 LOCATE0,1:FORZ=1TO31:PRINTCHR$(17);:NEXTZ
51490 SM=0:D$=ZD$:GOSUB3200:GOTO465
51499 'TT$-EDIT
51500 $=""
51505 LOCATE0,0:INPUT"";@21;T$
51510 RESTORE#:RESTORE#"()1":RESTORE#D$:TT$=D$+T$:WRITE#TT$
51520 RETURN
51549 'CREATE TT$
51550 LOCATE0,0:PRINTLEFT$(SP$,21);CSR0;:INPUT"";@21;T$
51555 IFLEN(T$)>21THENT$=""
51560 GOSUB51510:LOCATE0,0:PRINTLEFT$(DP$,21);:TT$=D$+T$:GOTO530
51599 '1./2. OUT-IN
51600 LOCATE0,P1:FORZ=1TO31:PRINTCHR$(17);:NEXTZ
51610 FORZ=1TOLEN(Z$)
51620 LOCATE0,P2:PRINTRIGHT$(Z$,Z);:NEXTZ
51630 FORZ=1TO300:NEXTZ:RETURN
51699 'IN-OUT 2
51700 FORZ=1TOLEN(Z$)
51710 LOCATE0,P1:PRINTRIGHT$(Z$,Z);:NEXTZ
51720 LOCATE0,P2:FORZ=1TO31:PRINTCHR$(17);:NEXTZ
51730 FORZ=1TO300:NEXTZ:RETURN
51998 'SCHUL-BETRIEB
51999 'DD$ VERARBEITEN SUB
52000 IFTI=9THENTI$=LEFT$(TI$,3):P=15
52010 IFTI=10THENTI$=LEFT$(TI$,2):P=16
52020 IFTI=13THENTI$=LEFT$(TI$,7):P=8
52030 IFTI=14THENTI$=LEFT$(TI$,6):P=13
52040 PRINTTP$(TI);
52050 IFLEN(TI$)<8THENLOCATEP,1:PRINTTI$;
52060 LOCATE22,1:PRINTT$;
52070 RETURN
52199 'MON$-SAVE !
52200 M$="()"+RIGHT$(D$,6):M=VAL(LEFT$(D$,2)):Z=0
52210 RESTORE#:RESTORE#M$,,52260
52215 READ#$:IFDE=1THEN52245
52220 IFMD=0THENZ=0:GOTO52245
52222 FORMZ=1TOMD
52223 X$=DD$(MZ):X=VAL(LEFT$(X$,1))
52224 IFX<1ORX>8THEN52240
52225 A=VAL(MID$(X$,3,2)):T=-(A<12)-2*(A=>12)
52230 IFZ=3ORZ=T THEN52240
52235 Z=Z+T
52240 NEXTMZ
52245 MON$=LEFT$($,M+7)+RIGHT$(STR$(Z),1)+MID$($,M+9)
52250 RESTORE#:RESTORE#M$:WRITE#MON$:RETURN
52260 WRITE#M$+"0000000000000000000000000000000":GOTO52210
60000 DATASAMSTAG,SONNTAG,MONTAG,DIENSTAG,MITTWOCH,DONNERSTAG,FREITAG
60100 DATA---,Termin,Meeting,Telefon,TV-Prog,Doktor,Frist,Geb.,Hausaufgaben (   ) :,Klassenarbeit (  ) :,S. Ueberpruefung :,M. Ueberpruefung :,Info. (          ) :,Mitbringen (      ):
60200 DATA31,28,31,30,31,30,31,31,30,31,30,31