1 '(c)1993 by FCNă
10 IFZS=1THENCLEAR:GOSUB500:GOTO50
20 CLS:CLEAR:GOSUB500
22 CLS:PRINT"    SCHOOL - TERMINator                     (c)1993 by FCNă";:$=INPUT$(1,@)
23 PL=1:RESTORE#:RESTORE#"()3b",,25
24 PL=0
25 RESTORE#:RESTORE#"()CON",,28
26 READ#$:GOTO40
28 $="()CON"
30 CLS:INPUT"Installieren (J/N) ? ",$:IF$="N"THENI=1:GOTO50
33 RESTORE#:RESTORE#"()CON",,34
34 A=PEEK((PEEK(1771)+PEEK(1772)*256)+8)-48:IFA<0ORA>9THENCLS:PRINT"Installation unmoeglich !";:$=INPUT$(1,@):I=1:GOTO50
35 WRITE#"()CON"+STR$(A)+A$
37 GOTO50
40 IFMID$($,7,1)="-"THENA$=RIGHT$($,1):GOTO30
45 GOTO50
50 H=1:CLS:PRINT"-†TERMIN‡2†NOTEN‡3†PLAN‡4†NOTIZ  - bitte auswaehlen -    school";
55 IFTE=1THENLOCATE0,0:PRINT"1";
57 IFI=1THENLOCATE9,0:PRINT"-";
58 IFPL=1ANDI=1THENLOCATE17,0:PRINT"-";
60 $=INPUT$(1,@)
70 IF$="1"ANDTE=1THEN150
80 IF$="2"ANDI=0THEN135
90 IF$="3"AND(PL=0ORI=0)THEN3000
100 IF$="4"THEN4000
120 IF$=CHR$(8)THENIFTE=0THENCLS:CLEAR:PRINT"(c)1993";:END ELSECLS:ZS=1:GOTO#P
130 GOTO60
135 IFOK=1THEN600
137 RESTORE#:RESTORE#"()NOTE",,148
138 READ#$
140 $=MID$($,7)
141 GOSUB9300
142 IFRIGHT$(C$,1)="*"THENC=1:C$=LEFT$(C$,LEN(C$)-1)
143 IF$<>C$THENLOCATE13,1:PRINT"CODE FALSCH !!!   ":OK=0:GOTO50
144 IFC=1THENCLS:INPUT"NEW CODE:";C$ELSEGOTO147
145 RESTORE#:RESTORE#"()NOTE",,146
146 WRITE#"()NOTE"+C$
147 OK=1:C=0:GOTO600
148 OK=0:GOTO600
150 A=0:CLS:INPUT"Art> 9:HA 10:Arbeit 11:SU 12:HU 13:i 14:Mitbringen  >  ";@2;A
170 CLS
175 IFA<9ORA>14THEN50
180 IFA>9THENTP$=CHR$(A+55)ELSETP$="9"
190 INPUT"Bedingung (evtl.) : ";@10;G$
200 CLS:INPUT"Aufgaben/Fach : ";@9;T$
210 CLS:INPUT"Kommentar :"+CHR$(13);@30;C$:D$=""
220 CLS:INPUT"Datum : ";@8;D$
225 IFD$=""THEN50
230 CLS:PRINT"Saving ...";
240 $=TP$+"="+LEFT$(G$+"           ",11)+"="+LEFT$(T$+"         ",9)+C$
250 ERASEZ$:DIMZ$(50)
260 RESTORE#:RESTORE#"()1":RESTORE#D$,,400
270 READ#Z$(1):Z=2
280 READ#Z$(Z)
290 IFMID$(Z$(Z),2,1)<>"="THEN310
300 Z=Z+1:GOTO280
310 RESTORE#:RESTORE#"()1":RESTORE#D$
320 FORX=1TOZ-1:WRITE#:NEXTX
325 RESTORE#:RESTORE#"()1n":WRITE#
330 RESTORE#"@",,332
332 WRITE#Z$(1)
335 WRITE#$
340 FORX=2TOZ-1
350 WRITE#Z$(X)
360 NEXTX
365 WRITE#"()1n"
370 GOTO50
400 WRITE#D$
410 WRITE#$
415 WRITE#"()1n"
417 RESTORE#:RESTORE#"()1n":WRITE#
420 GOTO50
500 RESTORE#:RESTORE#"()TERMINator",,520:READ#$:P=VAL(RIGHT$($,2))
510 TE=1
520 RETURN
599 'NOTEN
600 RESTORE#:RESTORE#"()2",,610
605 GOSUB9000
606 IFD>0THENN=1ELSEN=0
607 GOTO620
610 WRITE#"()2","()2n":N=0:GOSUB9000:GOTO620
620 CLS:PRINT"1†FAECHER‡2†NOTEN‡3†PASSWORT EIN -";STR$(H);". Halbjahr -          noten";
630 IFN=0THENLOCATE10,0:PRINT"-";
635 IFOK=1THENLOCATE18,0:PRINT"-";
640 $=INPUT$(1,@)
650 IF$=CHR$(8)THEN50
660 IF$="1"THEN700
670 IF$="2"ANDN=1THEN800
680 IF$="3"ANDOK=0THENC=1:GOTO144
690 GOTO640
699 'FACH
700 F$="":CLS:INPUT"Fach : ";@6;F$
710 IFF$=""THEN606
720 F$=LEFT$(F$+"     ",6)
730 FORZ=1TOD
740 IFLEFT$(DD$(Z),6)=F$THEN760
750 NEXTZ
755 IFD=50THENPRINT"Nur 50 Faecher erlaubt !";:$=INPUT$(1,@):CLS:GOTO606ELSEZ$="":INPUT"Neues Fach ? ";@1;Z$
756 CLS:IFZ$="N"THEN606
758 D=D+1:DD$(D)=F$+"=-.--":GOSUB9100
759 GOTO700
760 Z$="":INPUT"Fach loeschen ? ";@1;Z$
770 CLS:IFZ$="N"THEN606
780 GOSUB9100:RESTORE#:RESTORE#"()2":RESTORE#F$:WRITE#:GOTO600
800 CLS:X=1
810 D$=LEFT$(DD$(X),6):N$=MID$(DD$(X),12):H$=MID$(DD$(X),8,4)
820 CLS:PRINTD$;"‡ ";N$;
830 $=INPUT$(1,@)
840 IF$=CHR$(30)ANDX>1THENX=X-1:GOTO810
850 IF$=CHR$(31)ANDX<D THENX=X+1:GOTO810
855 IF$="E"THENGOSUB1000:GOTO820
860 IF$=CHR$(13)THEN900
865 IF$="."THEN2100
870 IF$=CHR$(8)THENGOSUB9100:GOTO620
880 GOTO830
900 LOCATE8,0:INPUT"";@55;N$
910 PRINTCHR$(11);
920 DD$(X)=D$+"="+H$+N$
930 GOTO810
1000 $=DD$(X)+"                                                                   "
1002 CLS:PRINTD$;"‡ CALC ...";
1005 DIMA$(4),B$(8),A(4),B(8)
1010 Y=1:A=0:FORZ=12TO24STEP4
1020 Z$=MID$($,Z,3)
1030 IFZ$="   "THENA$(Y)="0"ELSEA$(Y)=Z$:A=A+1
1040 Y=Y+1:NEXTZ
1050 Y=1:B=0:FORZ=36TO64STEP4
1060 Z$=MID$($,Z,3)
1070 IFZ$="   "THENB$(Y)="0"ELSEB$(Y)=Z$:B=B+1
1080 Y=Y+1:NEXTZ
1090 FORZ=1TO4
1095 IFA$(Z)="0"THEN1130
1100 IFRIGHT$(A$(Z),1)<>" "THENA(Z)=VAL(A$(Z))+0.5:GOTO1130
1110 IFMID$(A$(Z),2,1)="+"THENA(Z)=VAL(A$(Z))-0.25
1120 IFMID$(A$(Z),2,1)="-"THENA(Z)=VAL(A$(Z))+0.25
1125 IFMID$(A$(Z),2,1)=" "THENA(Z)=VAL(A$(Z))
1130 NEXTZ
1140 FORZ=1TO8
1145 IFB$(Z)="0"THEN1190
1150 IFRIGHT$(B$(Z),1)<>" "THENB(Z)=VAL(B$(Z))+0.5:GOTO1190
1160 IFMID$(B$(Z),2,1)="-"THENB(Z)=VAL(B$(Z))+0.25
1170 IFMID$(B$(Z),2,1)="+"THENB(Z)=VAL(B$(Z))-0.25
1180 IFMID$(B$(Z),2,1)=" "THENB(Z)=VAL(B$(Z))
1190 NEXTZ
2000 C$="":IFA=0THENA$=" -.--":GOTO2020
2010 A$=STR$(ROUND((A(1)+A(2)+A(3)+A(4))/A,-3))
2020 IFB=0THENB$=" -.--":GOTO2040
2030 B$=STR$(ROUND((B(1)+B(2)+B(3)+B(4)+B(5)+B(6)+B(7)+B(8))/B,-3))
2035 IFA$<>" -.--"THENC$=STR$(ROUND((VAL(A$)+VAL(B$))/2,-3))
2040 CLS:PRINTD$;"‡   schriftl.   muendl.              ";A$;:LOCATE22,1:PRINTB$;:LOCATE0,1:PRINTC$;
2050 $=INPUT$(1,@)
2060 ERASEA,B,A$,B$:RETURN
2099 'HALBJAHR
2100 PRINTCHR$(11);"      ";CSR1;H$;CSR1;
2105 IFH=2THEN$=INPUT$(1,@):GOTO820
2110 INPUT"";@4;H$
2120 H$=LEFT$(H$+"    ",4)
2125 DD$(X)=D$+"="+H$+N$
2130 GOTO820
2800 X=1:FORZ=5TO140STEP27
2810 T$(X)=MID$($,Z,27)
2820 X=X+1:NEXTZ
2830 RETURN
2900 DATAMo,Di,Mi,Do,Fr,Sa
3000 CLS:DIMT$(6),W$(6):S$=""
3005 RESTORE2900:FORZ=1TO6:READW$(Z):NEXTZ
3010 RESTORE#:RESTORE#"()3b",,3020:READ#$:GOSUB2800
3015 GOTO3055
3020 FORZ=1TO6
3025 T$(Z)="--- --- --- --- --- --- ---"
3030 S$=S$+T$(Z)
3040 NEXTZ
3050 S$="()3b"+S$:WRITE#S$
3055 X=1
3060 PRINTCHR$(11);"     1   2   3   4   5   6  7/8  ";W$(X);":";T$(X);
3070 $=INPUT$(1,@)
3080 IF$=CHR$(30)ANDX>1THENX=X-1:GOTO3060
3090 IF$=CHR$(31)ANDX<6THENX=X+1:GOTO3060
3100 IF$=CHR$(13)THEN3200
3110 IF$=CHR$(8)THENERASE:IFED=1THENED=0:GOSUB3300:GOTO50ELSEGOTO50
3120 GOTO3070
3200 LOCATE4,1:INPUT"";@27;T$(X)
3210 PRINTCHR$(11);
3215 T$(X)=LEFT$(T$(X)+"                             ",27)
3220 ED=1:GOTO3060
3300 RESTORE#:RESTORE#"()3b"
3310 $="()3b":FORZ=1TO6
3320 $=$+T$(Z)
3330 NEXTZ
3340 WRITE#$
3350 RETURN
4000 $="":CLS:RESTORE#:RESTORE#"()4",,4010
4005 READ#Z$,$:GOTO4020
4010 WRITE#"()4"
4020 PRINT$;:LOCATE0,0:INPUT"";@255;$:CLS:IF$=""THEN$=" "
4025 RESTORE#:RESTORE#"()4":READ#Z$:WRITE#$
4030 GOTO50
8999 'READ
9000 ERASEDD$:DIMDD$(51)
9010 RESTORE#:RESTORE#"()2":READ#$
9015 Z=1
9020 READ#DD$(Z)
9030 IFMID$(DD$(Z),7,1)<>"="THEND=Z-1:AD=D:RETURN
9040 Z=Z+1:GOTO9020
9099 'SAVE
9100 RESTORE#:RESTORE#"()2"
9110 WRITE#
9120 FORZ=1TOAD
9130 WRITE#
9140 NEXTZ
9150 RESTORE#:RESTORE#"()2n":WRITE#
9160 RESTORE#"@",,9170
9170 WRITE#"()2"
9180 FORZ=1TOD
9190 WRITE#DD$(Z)
9200 NEXTZ
9210 WRITE#"()2n"
9220 AD=D:RETURN
9300 CLS:PRINT" * Secret: *";CHR$(13);" Enter Code: ";:C$=""
9310 FORZ=1TO18
9320 Z$=INPUT$(1)
9330 IFZ$=CHR$(13)THEN9360
9340 C$=C$+Z$
9345 PRINT"‡";
9350 NEXTZ
9360 RETURN